1.2 Wat is het aantal personeelsleden?

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Inhuurovereenkomst
• Onverplaatsbaar artefact
• Oproepovereenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 1.2
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT 
11	(?vestiging AS ?Indeling)
12    (SUM(?zorg_functie) AS ?Zorg)
13    (SUM(?niet_zorg_functie) AS ?Niet_zorg)
14    (COUNT(DISTINCT ?persoon) AS ?Totaal)
15{
16    SELECT
17    	?vestiging
18    	?persoon
19    	(MAX(?zorg) AS ?zorg_functie)
20    	(MAX(?niet_zorg) AS ?niet_zorg_functie)
21
22    {
23        #BIND("2024-06-12"^^xsd:date AS ?peildatum)
24        #BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
25        #BIND(onz-org:ZorgkantoorZilverenKruis AS ?zorgkantoor)
26
27        VALUES ?personeels_overeenkomst 
28        { 
29            onz-pers:ArbeidsOvereenkomst
30            onz-pers:OproepOvereenkomst
31            onz-pers:UitzendOvereenkomst
32            onz-pers:InhuurOvereenkomst
33        }
34        ?overeenkomst 
35            a ?personeels_overeenkomst ;
36            onz-pers:heeftOpdrachtnemer ?persoon ;
37            onz-g:hasPart ?overeenkomst_afspraak .
38        ?overeenkomst_afspraak
39            a onz-pers:WerkOvereenkomstAfspraak ;
40            onz-g:startDatum ?start_afspraak .
41        OPTIONAL {
42            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
43        FILTER(?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)))
44
45        ?overeenkomst_afspraak onz-g:isAbout ?functie .                
46        ?functie a onz-g:OccupationalPositionRole .
47
48        # Bepaal of de functie op de overeenkomst een ZorgverlenerFunctie is
49        BIND(IF(EXISTS{?functie a onz-pers:ZorgverlenerFunctie}, 1, 0) AS ?zorg)
50        BIND(IF(?zorg = 0, 1, 0) AS ?niet_zorg)
51
52        {   
53            # Vestiging
54            ?overeenkomst_afspraak onz-g:isAbout ?locatie .
55            ?locatie a onz-g:StationaryArtifact .
56            ?locatie onz-g:partOf* ?vestiging_uri .
57            ?vestiging_uri a onz-org:Vestiging ;
58                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 ;
59                onz-g:identifiedBy ?vest_nr .
60            ?vest_nr a onz-org:Vestigingsnummer ;
61            	onz-g:hasDataValue ?vestiging . 	
62
63            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
64            ?pc_gebied 
65            onz-g:identifiedBy ?postcode ;
66            onz-g:partOf+ ?zk_regio .
67            ?zk_regio a onz-org:ZorgkantoorRegio .
68            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
69        } 
70        UNION 
71        {   
72            # Organisatieniveau
73            BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
74        }
75
76    } 
77    GROUP BY ?persoon ?vestiging 
78} 
79GROUP BY ?vestiging
80ORDER BY ?vestiging
81